Clojure在简单循环和Java上的表现真的很糟糕

performance math java clojure

2022-09-01 10:35:02

剧透预警，这是欧拉计划的第5个问题。

我试图学习Clojure并解决了问题5，但它慢了几个数量级（Java中的1515 ms与Clojure中的169932 ms）。我甚至尝试使用类型提示，未经检查的数学运算和内联函数都为零。

为什么我的Clojure代码要慢得多？

Clojure code：

(set! *unchecked-math* true)
(defn divides? [^long number ^long divisor] (zero? (mod number divisor)))

(defn has-all-divisors [divisors ^long num]
  (if (every? (fn [i] (divides? num i)) divisors) num false))

(time (prn (some (fn [^long i] (has-all-divisors (range 2 20) i)) (iterate inc 1))))

Java 代码：

public class Problem5 {
  public static void main(String[] args) {
    long start = System.currentTimeMillis();
    int i = 1;
    while(!hasAllDivisors(i, 2, 20)) {
      i++;
    }
    long end = System.currentTimeMillis();
    System.out.println(i);
    System.out.println("Elapsed time " + (end - start));
  }

  public static boolean hasAllDivisors(int num, int startDivisor, int stopDivisor) {
    for(int divisor=startDivisor; divisor<=stopDivisor; divisor++) {
      if(!divides(num, divisor)) return false;
    }
    return true;
  }

  public static boolean divides(int num, int divisor) {
    return num % divisor == 0;
  }
}

答案 1

一些性能问题：

该调用正在为的每个增量创建一个新的懒惰数字列表。这很昂贵，并且会导致大量不必要的GC。(range 2 20)i
您正在通过传递函数调用来执行大量装箱操作。甚至每个增量都在做拳击/拆箱。(iterate inc 1)
您正在遍历一系列除数。这比直接迭代循环慢
mod实际上，目前在Clojure中并不是一个很好的优化函数。使用要好得多rem

您可以通过使用语句仅定义一次范围来解决第一个问题：let

(time (let [rng (range 2 20)]
  (prn (some (fn [^long i] (has-all-divisors rng i)) (iterate inc 1)))))
=> "Elapsed time: 48863.801522 msecs"

您可以使用循环/递归解决第二个问题：

(time (let [rng (range 2 20)
           f (fn [^long i] (has-all-divisors rng i))]
       (prn (loop [i 1] 
              (if (f i)
                i
                (recur (inc i)))))))
=> "Elapsed time: 32757.594957 msecs"

您可以通过在可能的除数上使用迭代循环来解决第三个问题：

(defn has-all-divisors [^long num]
  (loop [d (long 2)]
    (if (zero? (mod num d))
      (if (>= d 20) true (recur (inc d)))
      false)))

 (time (prn (loop [i (long 1)] (if (has-all-divisors i) i (recur (inc i))))))
 => "Elapsed time: 13369.525651 msecs"

您可以使用以下命令解决最终问题rem

(defn has-all-divisors [^long num]
  (loop [d (long 2)]
    (if (== 0 (rem num d))
      (if (>= d 20) true (recur (inc d)))
      false)))

 (time (prn (loop [i (long 1)] (if (has-all-divisors i) i (recur (inc i))))))
=> "Elapsed time: 2423.195407 msecs"

如您所见，它现在与Java版本具有竞争力。

一般来说，你通常可以通过一些努力使Clojure几乎和Java一样快。主要技巧通常是：

避免懒惰的功能特性。它们很好，但增加了一些开销，这在低级计算密集型代码中可能会有问题。
使用原始/未检查的数学
使用循环/递归而不是序列
确保您没有对 Java 对象进行任何反射（即并消除您发现的所有警告）(set! *warn-on-reflection* true)

答案 2

我无法重现1500毫秒的性能。Clojure代码在编译到uberjar后似乎比Java版本快两倍。

Now timing Java version
    232792560
"Elapsed time: 4385.205 msecs"

Now timing Clojure version
    232792560
"Elapsed time: 2511.916 msecs"

我把java类放在 resources/HasAllDivisors 中.java

public class HasAllDivisors {

    public static long findMinimumWithAllDivisors() {
        long i = 1;
        while(!hasAllDivisors(i,2,20)) i++;
        return i;
    }

    public static boolean hasAllDivisors(long num, int startDivisor, int stopDivisor) {
        for(int divisor = startDivisor; divisor <= stopDivisor; divisor++) {
            if(num % divisor > 0) return false;
        }
        return true;
    }

    public static void main(String[] args){
        long start = System.currentTimeMillis();
        long i = findMinimumWithAllDivisors();
        long end = System.currentTimeMillis();
        System.out.println(i);
        System.out.println("Elapsed time " + (end - start));
    }

}

在克洛朱尔

(time (prn (HasAllDivisors/findMinimumWithAllDivisors)))

(println "Now timing Clojure version")
(time
    (prn
        (loop [i (long 1)]
            (if (has-all-divisors i)
                i
                (recur (inc i))))))

即使在命令行上，java类也不会重现快速的速度。

$ time java HasAllDivisors
  232792560
Elapsed time 4398

real   0m4.563s
user   0m4.597s
sys    0m0.029s