无法解析 com.google.android.gms play-services-auth：11.4.0

android java android-gradle-plugin google-play-services android-support-library

2022-09-01 03:24:21

我正在尝试为Android FirebaseUI编写代码 - 在我的Android项目中进行身份验证，但从最近两天开始，我在当前代码中遇到错误，不知道如何修复它。努力尝试，但以正确的方式没有发生任何事情。

这是我的build.gradle（项目：友好聊天）

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        jcenter()
        mavenLocal()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.2.2'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
        classpath 'com.google.gms:google-services:3.0.0'
    }
}

allprojects {
    repositories {
        jcenter()
        mavenLocal()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

这是我的build.gradle（模块：应用程序）

apply plugin: 'com.android.application'
apply plugin: 'com.google.gms.google-services'

repositories {
    mavenLocal()
    flatDir {
        dirs 'libs'
    }
}

android {
    compileSdkVersion 24
    buildToolsVersion "24.0.1"

    defaultConfig {
        applicationId "com.google.firebase.udacity.friendlychat"
        minSdkVersion 16
        targetSdkVersion 24
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    packagingOptions {
        exclude 'META-INF/LICENSE'
        exclude 'META-INF/LICENSE-FIREBASE.txt'
        exclude 'META-INF/NOTICE'
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])

    // Displaying images
    compile 'com.android.support:design:24.2.1'
    compile 'com.android.support:appcompat-v7:24.2.1'
    compile 'com.github.bumptech.glide:glide:3.6.1'
    compile 'com.google.firebase:firebase-database:11.0.4'
    compile 'com.google.firebase:firebase-auth:11.0.4'
   compile 'com.google.android.gms:play-services-auth:11.4.0'

    testCompile 'junit:junit:4.12'
}

答案 1

无法解析 com.google.android.gms play-services-auth：11.4.0 .

添加到根级别文件maven { url "https://maven.google.com" }build.gradle

allprojects {
    repositories {
        jcenter()
        maven {
            url "https://maven.google.com"
        }
    }
}

从 11.2.0 开始需要此 maven 存储库。

您也可以使用快捷方式，但在使用之前请检查要求。google()

还要注意，因为你使用的是不同的版本。使用相同的版本。

compile 'com.google.firebase:firebase-database:11.0.4'
compile 'com.google.firebase:firebase-auth:11.0.4'
compile 'com.google.android.gms:play-services-auth:11.4.0'

更新

Firebase Android SDK 和 Google Play Services 库现在具有独立的版本号，允许更频繁、更灵活的更新。将谷歌播放服务gradle插件版本更新到最新版本（至少3.3.1）。

classpath 'com.google.gms:google-services:4.0.1'

并将库更新到最新版本。

答案 2

将存储库添加到“build.gradle”文件中。此 gradle 方法等效于。google()maven { url "https://maven.google.com" }

repositories {
    jcenter()
    google()
}