是否可以使用 gradle 'application' 插件指定多个主类

将类似如下的内容添加到根 build.gradle 中：

// Creates scripts for entry points
// Subproject must apply application plugin to be able to call this method.
def createScript(project, mainClass, name) {
  project.tasks.create(name: name, type: CreateStartScripts) {
    outputDir       = new File(project.buildDir, 'scripts')
    mainClassName   = mainClass
    applicationName = name
    classpath       = project.tasks[JavaPlugin.JAR_TASK_NAME].outputs.files + project.configurations.runtimeClasspath
  }
  project.tasks[name].dependsOn(project.jar)

  project.applicationDistribution.with {
    into("bin") {
      from(project.tasks[name])
      fileMode = 0755
    }
  }
}

然后从根项目或子项目按如下方式调用它：

// The next two lines disable the tasks for the primary main which by default
// generates a script with a name matching the project name. 
// You can leave them enabled but if so you'll need to define mainClassName
// And you'll be creating your application scripts two different ways which 
// could lead to confusion
startScripts.enabled = false
run.enabled = false

// Call this for each Main class you want to expose with an app script
createScript(project, 'com.foo.MyDriver', 'driver')

我结合了这两个答案的部分内容，得出了相对简单的解决方案：

task otherStartScripts(type: CreateStartScripts) {
    description "Creates OS specific scripts to call the 'other' entry point"
    classpath = startScripts.classpath
    outputDir = startScripts.outputDir
    mainClassName = 'some.package.app.Other'
    applicationName = 'other'
}

distZip {
    baseName = archivesBaseName
    classifier = 'app'
    //include our extra start script 
    //this is a bit weird, I'm open to suggestions on how to do this better
    into("${baseName}-${version}-${classifier}/bin") {
        from otherStartScripts
        fileMode = 0755
    }
}

startScripts 是在应用应用程序插件时创建的。