使用基于通过/失败百分比子作业的 Groovy 脚本设置 Jenkins 多作业构建结果

不确定这是否真的有资格作为答案。可能更像是一个注释，但注释并不真正适合长代码片段，所以这里去了。

为了使您的代码更具可读性并且更易于浏览，我执行以下操作：

• 将 getXX 和 setYY 的所有实例替换为时髦的属性访问，例如build.getResult()build.result
• 删除了在函数调用中对 parens 的不必要使用，例如 成为log('ERROR: ${e.getMessage()}')log 'ERROR: ${e.getMessage()}'
• 将单引号中的字符串插值替换为双引号，因为字符串插值在单引号中不起作用。例如： 成为log 'ERROR: ${e.message}'log "ERROR: ${e.message}"
• 从声明脚本全局绑定作用域中的所有变量切换到本地，例如 成为。在全局范围内声明所有内容会导致难以发现的问题，尤其是在重用变量名称（如 ）subJob = ...def subJob = ...job

我还清理了一些冗余，例如：

job.getLastBuild().getSubBuilds().each { subBuild->
  subJob = subBuild.getJobName() 
  subJobNumber = subBuild.getBuildNumber()
  job = hudson.model.Hudson.instance.getItem(subBuild.getJobName())  // <---
  ...
  //println subBuild
  dePhaseJob = hudson.model.Hudson.instance.getItem(subBuild.getJobName()) // <---
  dePhaseJobBuild = dePhaseJob.getBuildByNumber(subBuild.getBuildNumber())

因此，在这里我们将两者设置为相同的值。像这样将相同的值分配给两个单独的变量是多余的，只会使代码更难阅读。jobdePhaseJob

此外（我对 jenkins 内部 api 不是很熟悉，所以我可能在这里错了），上面代码中的以程似乎不对：

• 我们有实例subBuild
• 然后，我们将相应的作业实例检索到两者中，并且jobdePhaseJob
• 然后，我们将构建检索到使用dePhaseJobBuilddePHaseJob.getBuildByNumber(subBuild.buildNumer)

但这不会给我们留下吗？也就是说，我们花费所有这些代码只是为了检索我们已经拥有的值。我们从构建到作业，再回到构建。除非我在 jenkins apis 中遗漏了一些深奥的东西，否则这似乎也是多余的。subBuild == dePhaseJobBuild

通过所有这些更改和其他一些小更改，我们使用以下代码进行撤消：

def job(name) {
  hudson.model.Hudson.instance.getItem(name) 
}

def aggregateResults() {
  def mainJobName = manager.build.project.name
  log '-------------------------------------------------------------------------------------'
  log 'Aggregated status report'
  log '-------------------------------------------------------------------------------------'
  log "${mainJobName}    #${manager.build.number} - ${manager.build.result}"

  def failed = false
  job(mainJobName).lastBuild.subBuilds.each { subBuild ->
    log "${subBuild.jobName}   #${subBuild.buildNumber} - ${subBuild.result}"
    log subBuild.log

    subBuild.subBuilds.each { subSubBuild ->
      try {
        log "   ${subSubBuild.jobName}   #${subSubBuild.buildNumber} - ${subSubBuild.result}"
        log "   " + subSubBuild.getLog(Integer.MAX_VALUE).join("\n   ") //indent the log lines

        if(!failed && subSubBuild.result.isWorseThan(threshold)) {
          failed = true
        }
      } catch (Exception e) {
        log "ERROR: ${e.message}"
        failed = true
      }
    }
  }

  if(failed) {
    manager.build.result = hudson.model.Result.FAILURE
  }
}

再说一遍，我没有一个jenkins实例来测试它，所以我在这里在黑暗中飞行，并提前为拼写错误，语法笨拙或其他滥用代码和jenkins apis而道歉。

代码中的问题（比如我看不到的字符串插值）使我认为原始代码不起作用，而是一个示例模式。

这让我进一步怀疑你是否真的需要在这里做两个级别的嵌套，即是以下几点：

job(mainJobName).lastBuild.subBuilds.each { subBuild ->
  subBuild.subBuilds.each { subSubBuild ->
    ...
  }
}

真的有必要还是一个级别就足够了？从您问题中的快速图表来看，我们似乎只需要关心主工作及其子工作，而不是子工作。

如果是这种情况，您可以按照以下方式逃脱逻辑：

def aggregateResults() {
  def mainJob = job(manager.build.project.name)
  def subs    = mainJob.lastBuild.subBuilds
  def total   = subs.size()
  def failed  = subs.findAll { sub -> sub.result.isWorseThan(threshold) }.size()

  if(failed > 0) {
    manager.build.result = hudson.model.Result.FAILURE
  }

  failed == 0 ? "green" : (failed/total < 0.25 ? "yellow" : "red")
}