配置 Gradle 以发布源代码和 javadoc

自 Gradle 6.0 起的解决方案

以下是如果您使用的是Gradle 6.0或更高版本，则可以使用的最低配置;注意新引入的 withSourcesJar（） 和 withJavadocJar（） 方法：

plugins {
    id 'java'
    id 'maven-publish'
}

group = 'com.example'

java {
    withSourcesJar()
    withJavadocJar()
}

publishing {
    repositories {
        maven {
            url = 'file:///tmp/my-repo'
        }
    }
    publications {
        myJava(MavenPublication) {
           from components.java
       }
    }
}

当然，您也可以使用插件代替.ivy-publishmaven-publish

另请参阅 Gradle 文档：

• 关于两种新方法
• 在 maven-publish 插件上
• 在常春藤发布插件上

2017年，Gradle 4.0版：

apply plugin: 'maven'
apply plugin: 'maven-publish'

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            artifact sourceJar
            artifact packageJavadoc
        }
    }
}

javadoc {
  source = sourceSets.main.allJava
  classpath = configurations.compileClasspath

  options
  {
    setMemberLevel JavadocMemberLevel.PUBLIC
    setAuthor true

    links "https://docs.oracle.com/javase/8/docs/api/"
  }
}

task sourceJar(type: Jar) {
  classifier = 'sources'
  from sourceSets.main.allJava
}

task packageJavadoc(type: Jar) {
    from javadoc
    classifier = 'javadoc'
}

适用于 和gradle publishgradle publishToMavenLocal