ANTLR：有没有一个简单的例子？

注意：这个答案是针对ANTLR3的！如果您正在寻找ANTLR4示例，那么此问答演示了如何使用ANTLR4创建简单的表达式解析器和计算器。

首先创建一个语法。下面是一个小语法，可用于计算使用 4 个基本数学运算符构建的表达式：+、-、* 和 /。您还可以使用括号对表达式进行分组。

请注意，这个语法只是一个非常基本的语法：它不处理一元运算符（-1 + 9中的减号）或小数点，如.99（没有前导数），仅举两个缺点。这只是一个你可以自己工作的例子。

以下是语法文件 Exp.g 的内容：

grammar Exp;

/* This will be the entry point of our parser. */
eval
    :    additionExp
    ;

/* Addition and subtraction have the lowest precedence. */
additionExp
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

/* Multiplication and division have a higher precedence. */
multiplyExp
    :    atomExp
         ( '*' atomExp 
         | '/' atomExp
         )* 
    ;

/* An expression atom is the smallest part of an expression: a number. Or 
   when we encounter parenthesis, we're making a recursive call back to the
   rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
    :    Number
    |    '(' additionExp ')'
    ;

/* A number: can be an integer value, or a decimal value */
Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

/* We're going to ignore all white space characters */
WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

（分析器规则以小写字母开头，词法分析器规则以大写字母开头）

创建语法后，您需要从中生成解析器和词法分析器。下载 ANTLR jar 并将其存储在与语法文件相同的目录中。

在 shell/命令提示符下执行以下命令：

java -cp antlr-3.2.jar org.antlr.Tool Exp.g

它不应该产生任何错误消息，现在应该生成ExpLexer.java ExpParser.java和Exp.tokens文件。

若要查看它是否正常工作，请创建以下测试类：

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        parser.eval();
    }
}

并编译它：

// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java

// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java

然后运行它：

// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo

// Windows
java -cp .;antlr-3.2.jar ANTLRDemo

如果一切顺利，则不会将任何内容打印到控制台。这意味着解析器没有发现任何错误。当您更改为，然后重新编译并运行它时，应打印以下内容："12*(5-6)""12*(5-6"

line 0:-1 mismatched input '<EOF>' expecting ')'

好了，现在我们想在语法中添加一些Java代码，以便解析器实际上做一些有用的事情。添加代码可以通过在语法中放置一些普通的Java代码来完成。{}

但首先：语法文件中的所有解析器规则都应返回一个原始的双精度值。您可以通过在每个规则之后添加以下内容来执行此操作：returns [double value]

grammar Exp;

eval returns [double value]
    :    additionExp
    ;

additionExp returns [double value]
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

// ...

这几乎不需要解释：每个规则都应该返回一个双精度值。现在，要从代码块内部与返回值（不在普通 Java 代码块内）“交互”，您需要在 前面添加一个美元符号：double value{...}value

grammar Exp;

/* This will be the entry point of our parser. */
eval returns [double value]                                                  
    :    additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
    ;

// ...

这是语法，但现在添加了Java代码：

grammar Exp;

eval returns [double value]
    :    exp=additionExp {$value = $exp.value;}
    ;

additionExp returns [double value]
    :    m1=multiplyExp       {$value =  $m1.value;} 
         ( '+' m2=multiplyExp {$value += $m2.value;} 
         | '-' m2=multiplyExp {$value -= $m2.value;}
         )* 
    ;

multiplyExp returns [double value]
    :    a1=atomExp       {$value =  $a1.value;}
         ( '*' a2=atomExp {$value *= $a2.value;} 
         | '/' a2=atomExp {$value /= $a2.value;}
         )* 
    ;

atomExp returns [double value]
    :    n=Number                {$value = Double.parseDouble($n.text);}
    |    '(' exp=additionExp ')' {$value = $exp.value;}
    ;

Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

由于我们的规则现在返回双精度值，因此请将您的 ANTLRDemo.java更改为：eval

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        System.out.println(parser.eval()); // print the value
    }
}

再次（重新）从语法（1）生成一个新的词法分析器和解析器，编译所有类（2）并运行ANTLRDemo（3）：

// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .:antlr-3.2.jar ANTLRDemo            // 3

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .;antlr-3.2.jar ANTLRDemo            // 3

现在，您将看到将表达式的结果打印到您的控制台！12*(5-6)

再说一遍：这是一个非常简短的解释。我鼓励您浏览ANTLR维基并阅读一些教程和/或玩一下我刚刚发布的内容。

祝你好运！

编辑：

这篇文章展示了如何扩展上面的示例，以便可以提供在提供的表达式中保存变量的 a。Map<String, Double>

为了让这段代码与当前版本的Antlr（2014年6月）一起使用，我需要做一些更改。 需要成为 ，返回值需要从 更改为 ，并且我需要删除末尾的子句，因为不再允许诸如属性值出现在词法分析器操作中。ANTLRStringStreamANTLRInputStreamparser.eval()parser.eval().valueWS$channel

加布里埃尔·托马塞蒂（Gabriele Tomassetti）的ANTLR超级教程非常有帮助

它有语法示例，不同语言（Java，JavaScript，C#和Python）的访问者示例以及许多其他内容。强烈推荐。

编辑：Gabriele Tomassetti关于ANTLR的其他有用文章

• 在 C 语言中开始使用 ANTLR#
• 在C++年开始使用 ANTLR