正确安装 java 8 和 java 7

java java-8 java-7

2022-09-01 06:26:15

我已经在我的Windows 7计算机上安装了JDK 1.7，安装JDK 1.8 u20后，我遇到了以下错误：

C:\>java -version
Error: Registry key 'Software\JavaSoft\Java Runtime Environment'\CurrentVersion'
has value '1.8', but '1.7' is required.
Error: could not find java.dll
Error: Could not find Java SE Runtime Environment.

我的变量指向旧版本（即1.7）。PATH

这里出了什么问题，我如何将java 8与java 7一起使用？

答案 1

问题是Java 8安装了很多你并不真正需要的东西：

\windows\system32 包含 Java 8 java.exe、javaw.exe 和 javaws.exe。您的路径可能在开始时有 system32，因此默认情况下，这些路径往往会运行。
系统路径变量以 C：\programdata\Oracle\Java\javapath 开头。此文件夹包含 java.exe、javaw.exe 和 javaws.exe作为 JRE 8 可执行文件的符号链接。

我已经删除了system32文件，并从系统路径中删除了C：\programdata\Oracle\Java\javapath。这似乎可以解决问题。我现在可以通过将JAVA_HOME和 PATH 指向相应的文件夹来切换版本。

甲骨文似乎决心要让运行多个版本变得困难。这在JRE中是可以理解的，但对于JDK来说却是疯狂的，因为开发人员几乎总是需要多个版本的Java。

编辑：我发现这个批处理脚本对于切换JDK很有用。用法：jdk.bat 6|7|8。您可能必须编辑 Java 的安装位置。

@echo off
if "%1"=="" goto report
set _version=%1
shift
if "%1"=="DBG" shift & echo on
set _command=%1 %2 %3 %4 %5

set _jdkdir=
set _jdkver=
for /D %%f in ("C:\Program Files\java\"jdk1.%_version%.*) do call :found "%%f"
if "%_jdkdir%"=="" goto notfound

set java_home=C:\Program Files\java\%_jdkdir%
call :javapath
path %new_path%
goto :report

:javapath
    setlocal enabledelayedexpansion
    set _jdirs=
    for /D %%j in ("C:\Program Files\java\*") do set _jdirs=!_jdirs!#%%~fj\bin
    set _jdirs=%_jdirs%#

    set _javabin=%java_home%\bin
    set _fpath="%PATH:;=" "%"
    call :checkpath %_fpath%
    endlocal & set new_path=%_javabin%
goto :eof

:checkpath
    if _%1==_ goto :eof
    echo %_jdirs% | find /i "#%~1#" 1>nul 2>&1
    set _err=%errorlevel%
    if not %_err%==0 set _javabin=%_javabin%;%~1
    if %_err%==0 echo Removed %~1 from path
    shift
    goto :checkpath

:report
javac -version
%_command%
goto :eof

:notfound
echo No JDK matching [C:\Program Files\java\jdk1.%_version%.*] found.
goto :eof

:found
set _jdkdir=%~n1%~x1
for /F "tokens=2,3 delims=." %%a in ("%_jdkdir%") do set _jdkver=1.%%a.%%b
goto :eof

答案 2

在“开始”菜单中键入“注册表编辑器”以打开注册表编辑器

转到左侧注册表资源管理器/树菜单上的“HKEY_LOCAL_MACHINE”

单击“HKEY_LOCAL_MACHINE”注册表中的“软件”

单击“软件”注册表中的“JavaSoft”

单击“JavaSoft”注册表列表中的“Java 运行时环境”，您可以看到已安装的 java 的不同版本

单击“Java运行时环境” - 在右侧，您将获得4-5行。请选择“当前版本”并右键单击（选择修改选项）将版本更改为“1.7”

现在魔术已经完成了