如何在语法上实现JJTree123456

parsing java compiler-construction abstract-syntax-tree javacc

2022-09-03 08:32:53

我有一个任务，就是使用JavaCC为讲师提供的语言制作一个带有语义分析的自上而下的解析器。我已经写好了生产规则，没有错误。我完全被困在如何使用JJTree作为我的代码上，我在互联网上搜索教程的时间并没有让我得到任何东西。只是想知道有人可以花一些时间来解释如何在代码中实现JJTree吗？或者，如果在某个地方有一个隐藏的分步教程，那将是一个很大的帮助！

以下是我的一些生产规则，以防它们有所帮助。提前致谢！

void program() : {}
{
  (decl())* (function())* main_prog()
}

void decl() #void : {}
{
  (
    var_decl() | const_decl()
   )
}

void var_decl() #void : {}
{
  <VAR> ident_list() <COLON> type()
 (<COMMA> ident_list() <COLON> type())* <SEMIC>
}

void const_decl()  #void : {}
{
  <CONSTANT> identifier() <COLON> type() <EQUAL> expression()
 ( <COMMA> identifier() <COLON> type() <EQUAL > expression())* <SEMIC>
} 

void function() #void : {}
{
  type() identifier() <LBR> param_list() <RBR>
  <CBL>
  (decl())*
  (statement() <SEMIC> )*
  returnRule() (expression() | {} )<SEMIC>
  <CBR>
}

答案 1

使用 JavaCC 创建 AST 看起来很像创建“普通”解析器（在文件中定义）。如果你已经有了一个有效的语法，它（相对）很容易:)jj

以下是创建 AST 所需的步骤：

将语法文件重命名为jjjjt
用根标签装饰它（斜体字是我自己的术语...）
调用你的语法，这将为你生成一个文件jjtreejjtjj
调用生成的语法javaccjj
编译生成的源文件java
测试它

这是一个快速的分步教程，假设您使用的是 MacOS 或 *nix，将文件放在与语法文件相同的目录中，并且位于系统的 PATH 上：javacc.jarjavajavac

1

假设您的语法文件名为，请重命名它：jjTestParser.jj

mv TestParser.jj TestParser.jjt

2

现在是棘手的部分：装饰您的语法，以便创建正确的AST结构。通过在 AST 之后（和之前）添加后跟一个标识符来修饰 AST（或节点或生产规则（完全相同））。在你最初的问题中，你在不同的制作中有很多，这意味着你正在为不同的生产规则创建相同类型的AST：这不是你想要的。#:#void

如果不修饰生产，则将使用生产的名称作为节点的类型（因此，您可以删除）：#void

void decl() :
{}
{
     var_decl()
  |  const_decl()
}

现在，该规则只是返回规则或返回的任何 AST。var_decl()const_decl()

现在让我们看一下（简化的）规则：var_decl

void var_decl() #VAR :
{}
{
  <VAR> id() <COL> id() <EQ> expr() <SCOL>
}

void id() #ID :
{}
{
  <ID>
}

void expr() #EXPR :
{}
{
  <ID>
}

我用类型装饰。现在这意味着此规则将返回以下树结构：#VAR

    VAR 
   / | \
  /  |  \
ID  ID  EXPR

如您所见，终端已从AST中丢弃！这也意味着和规则会丢失其终端匹配的文本。当然，这不是你想要的。对于需要保留终端匹配的内部文本的规则，您需要将树的显式设置为匹配终端的：idexpr<ID>.value.image

void id() #ID :
{Token t;}
{
  t=<ID> {jjtThis.value = t.image;}
}

void expr() #EXPR :
{Token t;}
{
  t=<ID> {jjtThis.value = t.image;}
}

导致输入如下所示："var x : int = i;"

       VAR 
        |
    .---+------.
   /    |       \
  /     |        \
ID["x"] ID["int"] EXPR["i"]

这就是您为AST创建适当结构的方法。下面是一个小语法，它是你自己语法的一个非常简单的版本，包括一个小方法来测试它：main

// TestParser.jjt
PARSER_BEGIN(TestParser)

public class TestParser {
  public static void main(String[] args) throws ParseException {
    TestParser parser = new TestParser(new java.io.StringReader(args[0]));
    SimpleNode root = parser.program();
    root.dump("");
  }
}

PARSER_END(TestParser)

TOKEN :
{
   < OPAR  : "(" > 
 | < CPAR  : ")" >
 | < OBR   : "{" >
 | < CBR   : "}" >
 | < COL   : ":" >
 | < SCOL  : ";" >
 | < COMMA : "," >
 | < VAR   : "var" >
 | < EQ    : "=" > 
 | < CONST : "const" >
 | < ID    : ("_" | <LETTER>) ("_" | <ALPHANUM>)* >
}

TOKEN :
{
   < #DIGIT    : ["0"-"9"] >
 | < #LETTER   : ["a"-"z","A"-"Z"] >
 | < #ALPHANUM : <LETTER> | <DIGIT> >
}

SKIP : { " " | "\t" | "\r" | "\n" }

SimpleNode program() #PROGRAM :
{}
{
  (decl())* (function())* <EOF> {return jjtThis;}
}

void decl() :
{}
{
     var_decl()
  |  const_decl()
}

void var_decl() #VAR :
{}
{
  <VAR> id() <COL> id() <EQ> expr() <SCOL>
}

void const_decl() #CONST :
{}
{
  <CONST> id() <COL> id() <EQ> expr() <SCOL>
}


void function() #FUNCTION :
{}
{
  type() id() <OPAR> params() <CPAR> <OBR> /* ... */ <CBR>
}

void type() #TYPE :
{Token t;}
{
  t=<ID> {jjtThis.value = t.image;}
}

void id() #ID :
{Token t;}
{
  t=<ID> {jjtThis.value = t.image;}
}

void params() #PARAMS :
{}
{
  (param() (<COMMA> param())*)?
}

void param() #PARAM :
{Token t;}
{
  t=<ID> {jjtThis.value = t.image;}
}

void expr() #EXPR :
{Token t;}
{
  t=<ID> {jjtThis.value = t.image;}
}

3

让类（包含在中）为您创建一个文件：jjtreejavacc.jarjj

java -cp javacc.jar jjtree TestParser.jjt

4

上一步已创建文件（如果一切正常）。让（也存在于）处理它：TestParser.jjjavaccjavacc.jar

java -cp javacc.jar javacc TestParser.jj

5

要编译所有源文件，请执行以下操作：

javac -cp .:javacc.jar *.java

（在Windows上，do： javac -cp .;javacc.jar *.java）

6

关键时刻已经到来：让我们看看一切是否真的有效！要让解析器处理输入，请执行以下操作：

var n : int = I; 

const x : bool = B; 

double f(a,b,c) 
{ 
}

执行以下命令：

java -cp . TestParser "var n : int = I; const x : bool = B; double f(a,b,c) { }"

并且您应该看到在主机上打印以下内容：

PROGRAM
 decl
  VAR
   ID
   ID
   EXPR
 decl
  CONST
   ID
   ID
   EXPR
 FUNCTION
  TYPE
  ID
  PARAMS
   PARAM
   PARAM
   PARAM

请注意，您没有看到匹配的文本，但相信我，它们就在那里。该方法根本没有显示它。IDdump()

呵呵

编辑

对于包含表达式的工作语法，您可以查看我的以下表达式计算器：https://github.com/bkiers/Curta（语法在中）。您可能希望了解如何在二进制表达式的情况下创建根节点。src/grammar

答案 2

下面是一个使用 JJTree http://anandsekar.github.io/writing-an-interpretter-using-javacc/